Das grosse Archiv mit 637
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Finanzmathematik (5) ->

Barwertformel statt der Funktion BW + Entnahmeplan (354)
 
 
Aufgabe
Die Funktion BW kann den Barwert nur vorschüssig oder nachschüssig errechnen. Barwerte von Zahlungen innerhalb einer Periode sind nicht darstellbar.

       A               B               C               D               E               F       
1 1.000,00  regelmäßige Zahlung      100.000,00  Einmalbetrag  
2 7,50%  Abzinsungssatz      5,00%  Abzinsungssatz  
3 12  Verrechnungen p.a.      Verrechnungen p.a.  
4 10  Jahre Laufzeit      Jahre Laufzeit  
5 nachschüssig         
6 20  Tage vorher      67.198,41  Barwert  
7            
8 84.595,40  Barwert         


Lösung
in A1 steht die regelmäßige Zahlung (als Beispiel 1.000)
in A2 steht der Abzinsungssatz (dezimal bzw. in % als Beispiel: 7,5 %)
in A3 stehen die Verrechnungen p.a. (als Beispiel: 12 - monatlich)
in A4 steht die Gesamt-Laufzeit in Jahren (als Beispiel 10)
in A5 steht entweder 0 (nachschüssige) oder 1 (vorschüssige) Verrechnung
in A6 stehen die Tage vor der nachschüssigen Fälligkeit (als Beispiel 20 = Zahlung jeweils am 10. eines Monats)

=(1+A2/A3)^(A3*A6/360)*WENN(UND(A5=1;A6=0);(A2+A3)/A3;1)*A1*A3*(1-(A3/(A3+A2))^(A3*A4))/A2

Obige (einfache) Formel - genauso auch wie BW - kommt mit gebrochenen Perioden (z.B. 10,1 Jahre bei vierteljährlicher Verrechnung) nicht zurecht.

Die gebrochene Periode liegt am Anfang:
=((1+A2/A3)^(A3*A6/360)*WENN(UND(A5=1;A6=0);(A2+A3)/A3;1)*A1*A3*(1-(A3/(A3+A2))^(GANZZAHL(A3*A4)))/A2+REST(A3*A4;1)*A1*WENN(UND(A5=1;A6=0);((A2+A3)/A3)^REST(A3*A4;1);1))/(1+(A2/A3))^REST(A3*A4;1)

Die gebrochene Periode liegt am Ende:
=(1+A2/A3)^(A3*A6/360)*WENN(UND(A5=1;A6=0);(A2+A3)/A3;1)*A1*A3*(1-(A3/(A3+A2))^(GANZZAHL(A3*A4)))/A2+(REST(A3*A4;1)*A1*WENN(UND(A5=1;A6=0);((A2+A3)/A3)^REST(A3*A4;1);1))/(1+(A2/A3))^(A3*A4)

Ergänzung vom 19.09.2006
Und nun das ganze umgekehrt: Du willst wissen, wie hoch die regelmäßige Zahlung sein muß, um einen vorgegebenen Barwert zu erreichen (Entnahmeplan).
Das funktioniert natürlich mit obigen Formeln per Zielwertsuche aber auch direkt.
In A1 steht jetzt der gewünschte Barwert - z.B. 100.000,-
Alle anderen obigen Parameter für dieses Beispiel unverändert.
=A1/((1+A2/A3)^(A3*A6/360)*WENN(UND(A5=1;A6=0);(A2+A3)/A3;1)*A3*(1-(A3/(A3+A2))^(A3*A4))/A2)
Ergebnis: 1.182,10


Barwert eines Einmalbetrages

in E1 steht der Einmalbetrag (z.B.: Restwert bei einer Finanzierung)
in E2 steht der Abzinsungssatz (dezimal bzw. in %)
in E3 stehen die Verrechnungen p.a.
in E4 steht die Gesamt-Laufzeit in Jahren

=E1/(1+E2/E3)^(E3*E4)
oder (BW ist hier auch richtig):
=BW(E2/E3;E4*E3;0;-E1;E4)



Erläuterung
Steht in A6 eine Zahl größer Null, ist der Eintrag in A5 egal.

Tage vor der nachschüssiger Fälligkeit wirken nur bei ganzen Perioden (die gebrochene Periode könnte ja kürzer sein, als die Tage in A6).

Das Ganze mit den gebrochenen Perioden hat eher einen akademischen touch; - denn bei einem Barwert von 5 Mio Euro differiert die einfache Formel um ca. 50 bis 200 Euro (je nach Verrechnung); - und die Nichtberücksichtigung der Tage vor der nachschüssigen Fälligkeit - wenn diese denn innerhalb der gebrochenen Periode lägen - würde sich im Cent-Bereich bewegen.

 
    zurück


 
powered by telltarget