Das grosse Archiv mit 637
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Finanzmathematik (5) ->

Übergang von degressiver Buchwert-AfA auf lineare AfA (190)
 
 
Aufgabe
Wie kann man einen Abschreibungsverlauf mit Wechsel von degressiver auf lineare Afa darstellen ?
Es soll auf die lineare AfA umgeschwenkt werden, wenn diese höher ist, als die degressive. (Der degressive AfA-Satz beträgt das doppelte des linearen; - maximal aber 20 %.)

       A               B               C               D       
1 12      100.000,00  
2 0,166667  16.666,67  83.333,33  
3   13.888,89  69.444,44  
4   11.574,07  57.870,37  
5   9.645,06  48.225,31  
6   8.037,55  40.187,76  
7   6.697,96  33.489,80  
8   5.581,63  27.908,16  
9   5.581,63  22.326,53  
10   5.581,63  16.744,90  
11   10  5.581,63  11.163,27  
12   11  5.581,63  5.581,63  
13   12  5.581,63  0,00  
14   0,00  0,00  
15 Wechsel       
16 im Jahr  7     


Lösung
in A1 steht die Lebensdauer des Objektes in (ganzen) Jahren
in A2 steht =MIN(2*1/A1;0,2)
(AfA-Satz maximal 20% / 30%: hinten 0,3

in B2 steht 1
in B3 steht:
=WENN(ODER(B2=A$1;B2=0);0;B2+1)
B3 runterkopieren

in C2 steht die AfA p.a.:
=WENN(B2=0;0;WENN(D1/(A$1-B1)>D1*A$2;D1/(A$1-B1);D1*A$2))
C2 runterkopieren

in D1 stehen die Anschaffungskosten und in der Folge die Restbuchwerte
in D2 steht:
=D1-C2
D2 runterkopieren

Das Jahr des Umschwenkens erhältst Du mit:
=INDEX(B1:B100;VERGLEICH(INDEX(C1:C100;VERGLEICH(A1;B1:B100;0));C1:C100;0))

Ist jetzt nur jährlich und ohne die diversen (bescheuerten) "Vereinfachungen" der Finanzämter und vor allem nicht stichtagsbezogen!

Erläuterung
Ergänzung vom 31.08.2006
Das Rad wurde doch nicht neu erfunden, denn bei einer Lebensdauer von unter 10 Jahren rechnet VDB FALSCH: der maximale AfA-Satz wird überschritten!
(Hinweis von Thomas Borchert)

Jens 01.04.2008:
VDB rechnet NICHT FALSCH, wenn die Formel so aussieht:
=VDB($D$1;0;$A$1;B2-1;B2;A1*A2;0)

Eigentlich haben wir mit dem Beitrag das Rad neu erfunden, denn für die Lösung gibt es auch die Standardfunktion VDB, die wir bislang nicht kannten. Schreibe in C2
=VDB($D$1;0;$A$1;B2-1;B2;20%*10;0)
kopiere die Formel nach unten und Du erhälst die Abschreibungsbeträge.
Der degressive Afa-Satz von 20% ist hier variabel. Und wenn der letzte Parameter von 0 auf 1 geändert wird, wird nicht auf linear umgestellt, sondern bleibt die Methode bis zum Ende der Laufzeit degressiv.


 
    zurück


 
powered by telltarget