Das grosse Archiv mit 637
VBA-freien Formellösungen und Tips
 
   
 
 ÜBER UNS   NEWS   FORMELN   TIPPS   KONTAKT   FORUM   LINKS 
   
Übersicht   Zauberbuch   Rätselbuch   Sparbuch   Bücher-Downloads / Errata  
 
Finanzmathematik (5) ->

Errechnung des Monatszinses aus Jahreszins und umgekehrt (148)
 
 
Aufgabe
Aus einem Nominal-Zinssatz (mit z.B. monatlicher Verrechnung) soll der effektive Jahreszins errechnet werden und umgekehrt.

Das erledigen auch die excelinternen Funktionen EFFEKTIV und NOMINAL; - aber nicht vorschüssig und schlimmer: das ADD-IN Analyse-Funktionen muß geladen sein.



Lösung
Effektivzins
Der Nominalzinssatz steht in A1 (Eingabe dezimal oder im %-Format)
Die Verrechnungen p.a. stehen in A2 (12=monatlich; 4=quartalsweise etc.)
In A3 steht entweder 0 (nachschüssige) oder 1 (vorschüssige Verrechnung)

Der Effektivzins (%-Format mit ausreichend Nachkommastellen):
=((1+A1/A2)^A2-1)*WENN(A3=1;1+A1/A2;1)


Nominalzins
Der Effektivzinssatz steht in A6
Die Verrechnungen p.a. stehen in A7

Der Nominalzins (nur nachschüssige Verrechnung):
=A7*(((1+A6)^(1/A7))-1)


Nominalzins (vorschüssige Verrechnung):
entweder über Zielwertsuche bei Effektivzins oder direkt mit

1. mit IKV
{=(RUNDEN(1/(1+IKV(WENN(ZEILE(INDIREKT("1:"&A7+2))-1=0;-A6;WENN(ZEILE(INDIREKT("1:"&A7+2))-1=1;-1;WENN(ZEILE(INDIREKT("1:"&A7+2))-1=A7+1;1;0)));0));7)-1)*A7}

2. mit Newton'schem Iterationsverfahren:
in D2 steht 1
in D3 steht
=D2-((-D2-$A$6+D2^($A$7+1))/(-1+($A$7+1)*D2^$A$7))
dies kopieren bis D10

=(D10-1)*A7 ergibt dann den Zinssatz


Erläuterung
Zur Berechnung des Nominalzinses bei vorschüssiger Verrechnung muß ein Polynom n-ter Ordnung gelöst werden.

Dies geschieht entweder mit der IKV-Funktion oder dem Newton'schen Iterationsverfahren. Bei dieser Anwendung ist Newton präziser (ab ca. der siebten Nachkommastelle).

Siehe dazu auch die Formeln
Nr. 291: Nullstellen-IKV
und
Nr. 292: Newton

 
    zurück


 
powered by telltarget